Belgian Amiga Club - ADF Collection/BS1 part 68.7z/BS1 part 68/Art Expression v2.04 (1996)(Soft-Logik Publishing)(Disk 1 of 3)[HD].7z/Art Expression v2.04 (1996)(Soft-Logik Publishing)(Disk 1 of 3)[HD].adf/Hard-Install

Text File | 1993-04-07 | 13KB | 356 lines

;ArtExpression Hard Drive Installation Script

;set up an error cleanup routine
(onerror
        (makeassign "AEinstpgm" (safe))
        (makeassign "BMEinstpgm" (safe))
)

;just started
(complete 0)

;cancel the assigns in case of installation restart
(makeassign "AEinstpgm" (safe))
(makeassign "BMEinstpgm" (safe))

;get the dest dir for Art Expression
(set ae_dest
        (tackon
                (askdir
                        (prompt "In which disk or drawer should ArtExpression be installed?")
                        (help @askdir-help)
                        (default @default-dest)
                )
                "ArtExpression"
        )
)

;lock on to volume 'AEprogram'
(askdisk
        (prompt "Please insert the disk labeled \"AEprogram\" into any drive")
        (help   "\n\n\n\nThe ArtExpression program and related files will be copied from the "
                        "\"AEprogram\" disk onto your system.")
        (dest  "AEprogram")
        (newname "AEinstpgm")
)

(complete 10)

;We now have a valid destination, so tell Installer where AE will end up
;so the exit page will be correct.
(set @default-dest ae_dest)

;copy program files from source to dest
(if
        (askbool
                (prompt "\n\n\n\n\nDo you want to copy the ArtExpression program?")
                (help "\n\n\n\nClicking 'Copy' will copy the ArtExpression program file to your disk. Clicking 'Do Not Copy' will skip to the next section of the installer.")
                (choices "Copy" "Do Not Copy")
                (default 1)
        )
        (copyfiles
                (source "AEinstpgm:ArtExpression")
                (dest ae_dest)
                (infos)
        )
)

;copy support files from source to dest
(if
        (askbool
                (prompt "\n\n\n\n\nDo you wish to copy the ArtExpression support files?")
                (help "\n\n\n\nClicking 'Copy' will copy the other files necessary to use ArtExpression to your disk.")
                (choices "Copy" "Do Not Copy")
                (default 1)
        )
        (copyfiles
                (source "AEinstpgm:")
                (dest ae_dest)
                (choices "AdobeIllustratorDict" "ArtExpression.prefs" "ArtExpressionDict2.04" "ArtExpression.colors")
        )
)

;copy the printer description file from source to dest
(copyfiles
        (source
                (tackon "AEinstpgm:Printers"
                        (select
                                (askchoice
                                        (prompt "Choose one of the files below that closely matches the PostScript printer you use." )
                    (help "\nIf you are not using a PostScript printer you may skip this section. \n\n "
                        "\nPostScript users: Choose the file that most closely matches the fonts resident in your PostScript printer. "
                        " This will allow ArtExpression to access the resident fonts rather than downloading them.")
                                        (choices
                                                "Standard35.prfonts"
                                                "Panasonic.prfonts"
                                                "TImicrolaserPS17.prfonts"
                                                "NECcolormate40.prfonts"
                                                "Adobe.prfonts"
                                                "VarityperOld.prfonts"
                                                "QMSps.prfonts"
                                                "QMScolorscript.prfonts"
                                                "DEC.prfonts"
                                                "NeXT.prfonts"
                                        )
                                )
                                "Standard35.prfonts"
                                "Panasonic.prfonts"
                                "TImicrolaserPS17.prfonts"
                                "NECcolormate40.prfonts"
                                "Adobe.prfonts"
                                "VarityperOld.prfonts"
                                "QMSps.prfonts"
                                "QMScolorscript.prfonts"
                                "DEC.prfonts"
                                "NeXT.prfonts"
                        )
                )
        )
        (dest ae_dest)
        (newname "ArtExpression.prfonts")
)

(complete 35)

;copy the Help files to dest/Help
(if
        (askbool
                (prompt "\n\n\n\n\nDo you wish to copy the ArtExpression Help Files?")
                (help "\n\n\n\nClicking 'Copy' will copy ArtExpression's Online Help files to your disk."
            " ")
                (choices "Copy" "Do Not Copy")
                (default 1)
        )
        (
                (makedir (tackon ae_dest "Help")
                        (infos)
                )
                (copyfiles
                        (source "AEinstpgm:Help")
                        (dest (tackon ae_dest "Help"))
                        (all)
                )
        )
)

;copy the Tutorial files to dest/Help
(if
        (askbool
                (prompt "\n\n\n\n\nDo you wish to copy the ArtExpression Tutorial Art Files?")
                (help "\n\n\n\nClicking 'Copy' will copy the ArtExpression Tutorial files to your disk.")
                (choices "Copy" "Do Not Copy")
                (default 1)
        )
        (
                (makedir (tackon ae_dest "AEart")
                        (infos)
                )
                (copyfiles
                        (source "AEinstpgm:AEart")
                        (dest (tackon ae_dest "AEart"))
                        (all)
                )
        )
)

(complete 45)

;the arp library is necessary for WB 1.3
(if
        (askbool (choices "Copy Arp.Library" "Do not Copy Arp.Library")
                 (prompt "\n\nDo you need the Arp.Library? \"Select Help for information on Arp.\"")
                 (help
                        "\n\nAmigaDOS 1.2 and 1.3 do not have a standard system file "
                        "requester. The Arp.Library provides a file requester to "
                        "BME and Art Expression. If you do not have the Arp.Library "
                        "file already installed, select Copy. If you are unsure "
                        "if you have it, select Copy. ArtExpression and BME will not "
                        "work with AmigaDOS 1.3 without the Arp.Library file!"
                        "\n\nAmigaDOS 2.0+ users should select Do not Copy.")
                 (default 1)
        )
        (copyfiles
                (source "AEInstPgm:libs/arp.library")
                (dest "LIBS:")
                (newname "arp.library")
        )
)
;the IFF library is necessary for AE to save IFF ILBM files
(if
        (askbool (choices "Copy IFF.Library" "Do not Copy IFF.Library")
                 (prompt "\n\nDo you need the IFF.Library? \"Select Help for information on IFF.\"")
                 (help
                        "\n\nArt Expression needs this file to save IFF ILBM bit maps of your drawings. "
                        " "
                        "\n\n\n If you do not have the IFF.Library "
                        "file already installed, select Copy.  If you are unsure "
                        "if you have it, select Copy. \n\n ArtExpression will not "
                        "be able to save your work in IFF ILBM bit mapped format without this library"
                        " .")
                 (default 1)
        )
        (copyfiles
                (source "AEInstPgm:libs/iff.library")
                (dest "LIBS:")
                (newname "iff.library")
        )
)

(complete 50)

;start of Fonts install
;now lock on to volume 'AEfonts1'
(if
        (askbool
                (prompt "\n\n\nDo you want to install fonts?")
                (default 1)
                (help
                        "\n\n\n\nThis section will copy "
                        "all of the fonts that are shipped with ArtExpression "
             "from AEfonts1 and AEfonts2 disks. "
                )
        )
        (
                (askdisk
                        (prompt "\nPlease insert the disk labeled \"AEfonts1\" into any drive.")
                        (help   "\n\n\nThe ArtExpression font files will be copied from the "
                                        "\"AEfonts1\" disk onto your system.")
                        (dest  "AEfonts1")
                        (newname "AEinstpgm")
                )
                (makedir (tackon ae_dest "AEfonts")
                        (infos)
                )
                (copyfiles
                        (source "AEinstpgm:AEfonts1")
                        (dest (tackon ae_dest "AEfonts"))
                        (all)
                )
                (askdisk
                        (prompt "\n\n\nPlease insert the disk labeled \"AEfonts2\" into any drive.")
                        (help   "\n\n\n\nThe ArtExpression font files will be copied from the "
                                        "\"AEfonts2\" disk onto your system.")
                        (dest  "AEfonts2")
                        (newname "AEinstpgm")
                )
                (copyfiles
                        (source "AEinstpgm:AEfonts2")
                        (dest (tackon ae_dest "AEfonts"))
                        (all)
                )

        )
)

;start of Convert install
(if
        (askbool
                (prompt "\n\n\n\n\nDo you want to install the ProDraw Clip to IFF-DR2D Converter?")
                (default 1)
                (help
                        "\n\nClicking 'Copy' will install "
                        "the ProDraw clip to IFF-DR2D structured drawing converter to your disk. "
            "\n\nThe Convert program converts Professional Draw Clip files to the Commodore standard IFF DR2D structured drawing format. "
            "ArtExpression and PageStream both support this format. "
                )
        )
        (
                (askdisk
                        (prompt "\n\nPlease insert the disk labeled \"AEfonts2\" into any drive.")
                        (help   "\n\n\n\nThe Converter will be copied from the "
                                        "\"AEfonts2\" disk onto your system.")
                        (dest  "AEfonts2")
                        (newname "AEinstpgm")
                )
                (copyfiles
                        (source "AEinstpgm:Convert")
                        (dest ae_dest)
                        (infos)
                        (newname "Convert")
                )
        )
)

(complete 85)

;start of BME Install
(if
        (askbool
                (prompt "\n\n\n\n\nDo you want to install BME with trace functions?")
                (default 1)
                (help
                        "\n\n\n\nClicking 'Copy' will install BME. \n"
            " \nBME is a Hotlinks compatible bitmap editor that has an AutoTrace "
            "feature used in one of the Art Expression tutorials. "
                )
        )
        (
                (set BME_dest
                        (tackon
                                (askdir
                                        (prompt "\nIn which disk or drawer should BME be installed?\n")
                                        (help @askdir-help)
                                        (default @default-dest)
                                )
                                "BME"
                        )
                )

                ; now lock on to volume 'BME'
                (askdisk
                        (prompt "\n\n\n\nPlease insert the disk labeled \"BME\".\n")
                        (help   "\n\n\n\nThe BME program and related files will be copied from the "
                                "\"BME\" disk into your system."
                        )
                        (dest  "BME")
                        (newname "BMEInstPgm")
                )

                (complete 90)

                (set @default-dest BME_dest)

                ;copy all program files from source to dest
                (copyfiles
                        (prompt "\n\nThis will create a new drawer called \"BME\" and "
                                "will copy the following files and drawers.\n "
                        )
                        (source "BMEInstPgm:BME")
                        (dest BME_dest)
                        (all)
                        (infos)
                        (confirm)
                        (help   "\n\nBME - is the program file.\n"
                                "Graphics - is a drawer containing the tutorial files.\n\n\n\n"
                                @copyfiles-help
                        )
                )

                ;un-snapshot the BME drawer icon
                (tooltype
                        (dest BME_dest)
                        (noposition)
                )

        )
)

(complete 98)

;un-snapshot the AE drawer icon
(tooltype
        (dest ae_dest)
        (noposition)
)

(set @default-dest ae_dest)

;done with the install
(complete 100)

; cleanup
(makeassign "AEinstpgm" (safe))
(makeassign "BMEinstpgm" (safe))

(exit)